If you put the following code in a file named ReplaceWithQuotes.BAT, and install the GnuWin sed utility, you should be able to use it as noted in the header comments to work around the {REPLACE...} issue with literal quote characters:
@ECHO OFF
GOTO Start
********************************************************************************
ReplaceWithQuotes.BAT <Directory> <BaseFilename> <Extension> <Placeholder> [-v]
********************************************************************************
Batch Arguments (in Simplify3D post-processing)
********************************************************************************
The <Directory> argument should be "[output_dir]".
The <BaseFilename> argument should be "[output_filename]"
The <Extension> argument does not include the dot.
The <Placeholder> argument should be the string to be replaced by double quotes.
The optional -v argument produces more log file information for troubleshooting.
********************************************************************************
Example Usage (in Simplify3D post-processing)
********************************************************************************
{REPLACE "; feature solid layer" "; feature solid layer\nM98 PDoubleQuotesSolidSettingsMacroDoubleQuotes"}
"<Directory>\ReplaceWithQuotes.BAT" "[output_dir]" "[output_filename]" gcode DoubleQuotes -v > <Directory>\QuoteLog.txt
********************************************************************************
This would result in all the lines which contained
; feature solid layer
to now be followed by the line:
M98 P"SolidSettingsMacro"
********************************************************************************
Description
********************************************************************************
Simplify3D 4.1.2 has a useful post-processing script facility (Scripts tab,
"Additional terminal commands for post processing"). The post-processing script
includes a {REPLACE...} feature, but nobody knows how to make it insert code
which includes double quotes. Possibly it can't. But some gcode commands take
parameters which require double quotes.
This batch file is part of a workaround. It's intended to be called from the
post-processing script, with arguments which enable it to find a gcode file
which contains a "placeholder" - a particular unique series of characters -
representing double quotes. The batch file uses the GnuWin sed utility to
substitute actual double quote characters for each instance of that placeholder
in the gcode file.
********************************************************************************
Issues
********************************************************************************
Simplify3D 4.1.2 post processing scripts have some problems with paths.
Provide the full path to this batch file, and quote it if it includes spaces.
Otherwise, it may silently fail. It's unclear where Simplify3D will look for it.
If you include a log file (redirection target), provide the full path, but be
sure it doesn't include any spaces and is unquoted. If you don't include a
complete path to the log file, the batch will silently fail to make the
replacements, and won't cretae a log either! If you include a complete path,
but either (or both) the path contains at least one space, or the filespec is in
quotes (ironically), the batch will make the replacements, but won't produce a
log file. If you don't include a log file (redirection), the batch will make the
replacements.
********************************************************************************
Don Stauffer, April 2021
********************************************************************************
: Start
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
:: Put parameters into variables with more descriptive names
SET Directory=%~1
SET BaseFilename=%~2
SET Extension=%~3
SET Placeholder=%~4
IF /i "%5" EQU "-v" SET IsVerbose=1
IF DEFINED IsVerbose (
@ECHO ReplaceWithDoubleQuotes.BAT
For /F "Tokens=*" %%I in ('Date /T') Do Set DateTime=%%I
For /F "Tokens=*" %%I in ('Time /T') Do Set DateTime=!DateTime!at %%I
@ECHO !DateTime!
)
:: Construct output and temporary filenames and filespecs
SET Filename="%BaseFilename%.%Extension%"
SET Filespec="%Directory%\%BaseFilename%.%Extension%"
SET TempFilename="%BaseFilename%_Temp.%Extension%"
SET TempFilespec="%Directory%\%BaseFilename%_Temp.%Extension%"
IF DEFINED IsVerbose (
@ECHO.
@ECHO Filename=%Filename%
@ECHO Filespec=%Filespec%
@ECHO TempFilename=%TempFilename%
@ECHO TempFilespec=%TempFilespec%
)
:: Construct and execute sed command
SET SedFilespec="C:\Program Files (X86)\GnuWin32\bin\sed.exe"
SET SedScript="s/%Placeholder%/\d34/g"
SET SedCommand=%SedFilespec% %SedScript% %Filespec%
IF DEFINED IsVerbose (
@ECHO.
@ECHO %SedCommand% ^> %TempFilespec%
)
%SedCommand% > %TempFilespec%
:: Replace output file with temporary file
IF DEFINED IsVerbose (
@ECHO.
@ECHO DEL %Filespec%
)
DEL %Filespec%
IF DEFINED IsVerbose (
@ECHO.
@ECHO REN %TempFilespec% %Filename%
)
REN %TempFilespec% %Filename%
